Qt SCXML Traffic Light QML Example (Dynamic)

A Qt Quick application that uses a dynamically loaded state machine to implement a traffic light.

Traffic Light QML Example (Dynamic) demonstrates how to connect to the active properties of a state in a dynamically loaded state machine.

The UI is created using Qt Quick.

Running the Example

To run the example from Qt Creator, open the Welcome mode and select the example from Examples. For more information, visit Building and Running an Example.

Dynamically Loading the State Machine

We link against the Qt SCXML module by adding the following line to the example .pro file:

 QT += qml scxml

We dynamically create the state machine in the main QML file:

 import QtScxml 5.8

 TrafficLight {
     StateMachineLoader {
         id: loader
         source: "qrc:///statemachine.scxml"
     }

     stateMachine: loader.stateMachine
 }

Connecting to States

In the SCXML file, we specify states for each light: red, yellow, and green. In the <onentry> element, we specify the event to send when entering the state and the delay in seconds before sending the event. In the <transition> element, we specify the event that triggers the transition to the state specified by the target attribute:

         <state id="red">
             <onentry>
                 <send event="startGoingGreen" delay="3s"/>
             </onentry>
             <transition event="startGoingGreen" target="redGoingGreen"/>
         </state>

         <state id="yellow" initial="greenGoingRed">
             <state id="redGoingGreen">
                 <onentry>
                     <send event="goGreen" delay="1s"/>
                 </onentry>
                 <transition event="goGreen" target="green"/>
             </state>

             <state id="greenGoingRed">
                 <onentry>
                     <send event="goRed" delay="1s"/>
                 </onentry>
                 <transition event="goRed" target="red"/>
             </state>
         </state>

         <state id="green">
             <onentry>
                 <send event="startGoingRed" delay="3s"/>
             </onentry>
             <transition event="startGoingRed" target="greenGoingRed"/>
         </state>

We connect to the states as follows:

     states: [
         State {
             name: "Red"
             when: stateMachine.red

             PropertyChanges {
                 target: redLight
                 opacity: 1
             }
         },
         State {
             name: "RedGoingGreen"
             when: stateMachine.redGoingGreen

             PropertyChanges {
                 target: redLight
                 opacity: 1
             }

             PropertyChanges {
                 target: yellowLight
                 opacity: 1
             }
         },
         State {
             name: "Yellow"
             when: stateMachine.yellow || stateMachine.blinking

             PropertyChanges {
                 target: yellowLight
                 opacity: 1
             }
         },
         State {
             name: "Green"
             when: stateMachine.green

             PropertyChanges {
                 target: greenLight
                 opacity: 1
             }
         }
     ]

Example project @ code.qt.io