2D sampling (u and v axes)

Computed functions or data generated for the pseudo-file '++' use samples generated along the u and v axes. This is a CHANGE from versions prior to 5.2 which sampled along the x and y axes. See special-filenames ++ (p. ). 2D sampling can be used in either plot or splot commands.

Example of 2D sampling in a 2D plot command. These commands generated the plot shown for plotstyle with vectors. See vectors (p. ).

    set urange [ -2.0 : 2.0 ]
    set vrange [ -2.0 : 2.0 ]
    plot '++' using ($1):($2):($2*0.4):(-$1*0.4) with vectors

Example of 2D sampling in a 3D splot command. These commands are similar to the ones used in sampling.dem. Note that the two surfaces are sampled over u and v ranges smaller than the full x and y ranges of the resulting plot.

    set title "3D sampling range distinct from plot x/y range"
    set xrange [1:100]
    set yrange [1:100]
    splot sample [u=30:70][v=0:50] '++' using 1:2:(u*v) lt 3, \
          [u=40:80][v=30:60] '++' using (u):(v):(u*sqrt(v)) lt 4

The range specifiers for sampling on u and v can include an explicit sampling interval to control the number and spacing of samples:

    splot sample [u=30:70:1][v=0:50:5] '++' using 1:2:(func($1,$2))