Description

Create an fsig stream by reading a selected channel from a PVOC-EX analysis file, with frame interpolation.

Syntax

fsig pvsdiskin SFname,ktscal,kgain[,ioffset, ichan]

Initialization

Sfname -- Name of the analysis file. This must have the .pvx file extension.

A multi-channel PVOC-EX file can be generated using the extended pvanal utility.

ichan -- (optional) The channel to read (counting from 1). Default is 1.

ioff -- start offset from beginning of file (secs) (default: 0) .

Performance

ktscal -- time scale, ie. the read pointer speed (1 is normal speed, negative is backwards, 0 < ktscal < 1 is slower and ktscal > 1 is faster)

kgain -- gain scaling.

Examples

Here is an example of the pvsdiskin opcode. It uses the file pvsdiskin.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac  ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o pvsdiskin.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100 
ksmps = 32 
0dbfs  = 1 
nchnls = 2

; by Menno Knevel 2021

; analyze sound file and output result to pvoc-ex file
ires system_i 1,{{ pvanal fox.wav fox.pvx }}          ; default settings

instr 1

ktscale	line 1, p3, .05			;change speed 
fsigr	pvsdiskin "fox.pvx", ktscale, 1	;read PVOCEX file
aout	pvsynth	fsigr			;resynthesise it
	outs	aout, aout

endin
</CsInstruments>
<CsScore>

i1 0 10.7  ; the fox jumps twice
e
</CsScore>
</CsoundSynthesizer>

Credits

New in Csound 5.06